[FILIPINO GUIDE] PAANO GUMAWA NG ERC20 TOKENS EASY STEPS!

[nakamura12]

Gusto mo bang gumawa ng token para sa iyong proyekto, gagawa ng komunidad sa mga tagasuporta sa pamamagitan ng pagbahagi ng tokens sa pamamagitan airdrop at marahil maglunsad ng ICO at sa ilang punto? Pagkatapos itong gabay ay para sayo!
Sa sunod-sunod na gabay na ito ipapakita ko sa inyo kung paano gagawa ng sariling ERC20 token at magsimulang ipamahagi ito sa pamamagitan ng einax.com token trading platform.

0. Kailangan may ETH ka
Upang makumpleto ang gabay na ito kailangan mo magkaroon ng halagang kahit $2 worth of Ethereum [ETH]. Sa gabay na ito gumamit ako ng Metamask Chrome Extenstion na kung saan pwede mo makuha dito: https://metamask.io/


1. Paggawa ng ERC20 Ethereum based token
Una, gusto naming mag-deploy ng smart contract na ERC20 ayon sa pamantayan.
Buksan mo ang Remix (kung saan may isang kahanga-hangang browser-based IDE para sa pag-unlad ng smart contract) sa pamamagitan ng pagsunod sa link na ito : https://remix.ethereum.org/. Sa pamamagitan ng default makikita mo ang ballot.sol smart contract. Maari mo nang e-close ang ballot.sol tab gumawa ng bago sa pagpindot ng binilugan na  "+" sign

Ngayon sa sandaling mayroon ka ng isang bagong walang laman na tab kopyahin ang code sa ibaba at i-paste mo ito sa Remix:

Code:

pragma solidity ^0.4.24;

// ----------------------------------------------------------------------------
// (c) BokkyPooBah / Bok Consulting Pty Ltd 2018. The MIT Licence.
// ----------------------------------------------------------------------------


// ----------------------------------------------------------------------------
// Safe maths
// ----------------------------------------------------------------------------
library SafeMath {
    function add(uint a, uint b) internal pure returns (uint c) {
        c = a + b;
        require(c >= a);
    }
    function sub(uint a, uint b) internal pure returns (uint c) {
        require(b <= a);
        c = a - b;
    }
    function mul(uint a, uint b) internal pure returns (uint c) {
        c = a * b;
        require(a == 0 || c / a == b);
    }
    function div(uint a, uint b) internal pure returns (uint c) {
        require(b > 0);
        c = a / b;
    }
}


// ----------------------------------------------------------------------------
// ERC Token Standard #20 Interface
// https://github.com/ethereum/EIPs/blob/master/EIPS/eip-20.md
// ----------------------------------------------------------------------------
contract ERC20Interface {
    function totalSupply() public constant returns (uint);
    function balanceOf(address tokenOwner) public constant returns (uint balance);
    function allowance(address tokenOwner, address spender) public constant returns (uint remaining);
    function transfer(address to, uint tokens) public returns (bool success);
    function approve(address spender, uint tokens) public returns (bool success);
    function transferFrom(address from, address to, uint tokens) public returns (bool success);

    event Transfer(address indexed from, address indexed to, uint tokens);
    event Approval(address indexed tokenOwner, address indexed spender, uint tokens);
}


// ----------------------------------------------------------------------------
// Contract function to receive approval and execute function in one call
//
// Borrowed from MiniMeToken
// ----------------------------------------------------------------------------
contract ApproveAndCallFallBack {
    function receiveApproval(address from, uint256 tokens, address token, bytes data) public;
}


// ----------------------------------------------------------------------------
// Owned contract
// ----------------------------------------------------------------------------
contract Owned {
    address public owner;
    address public newOwner;

    event OwnershipTransferred(address indexed _from, address indexed _to);

    constructor() public {
        owner = msg.sender;
    }

    modifier onlyOwner {
        require(msg.sender == owner);
        _;
    }

    function transferOwnership(address _newOwner) public onlyOwner {
        newOwner = _newOwner;
    }
    function acceptOwnership() public {
        require(msg.sender == newOwner);
        emit OwnershipTransferred(owner, newOwner);
        owner = newOwner;
        newOwner = address(0);
    }
}


// ----------------------------------------------------------------------------
// ERC20 Token, with the addition of symbol, name and decimals and a
// fixed supply
// ----------------------------------------------------------------------------
contract FixedSupplyToken is ERC20Interface, Owned {
    using SafeMath for uint;

    string public symbol;
    string public  name;
    uint8 public decimals;
    uint _totalSupply;

    mapping(address => uint) balances;
    mapping(address => mapping(address => uint)) allowed;


    // ------------------------------------------------------------------------
    // Constructor
    // ------------------------------------------------------------------------
    constructor() public {
        symbol = "FIXED";
        name = "Example Fixed Supply Token";
        decimals = 18;
        _totalSupply = 1000000 * 10**uint(decimals);
        balances[owner] = _totalSupply;
        emit Transfer(address(0), owner, _totalSupply);
    }


    // ------------------------------------------------------------------------
    // Total supply
    // ------------------------------------------------------------------------
    function totalSupply() public view returns (uint) {
        return _totalSupply.sub(balances[address(0)]);
    }


    // ------------------------------------------------------------------------
    // Get the token balance for account `tokenOwner`
    // ------------------------------------------------------------------------
    function balanceOf(address tokenOwner) public view returns (uint balance) {
        return balances[tokenOwner];
    }


    // ------------------------------------------------------------------------
    // Transfer the balance from token owner's account to `to` account
    // - Owner's account must have sufficient balance to transfer
    // - 0 value transfers are allowed
    // ------------------------------------------------------------------------
    function transfer(address to, uint tokens) public returns (bool success) {
        balances[msg.sender] = balances[msg.sender].sub(tokens);
        balances[to] = balances[to].add(tokens);
        emit Transfer(msg.sender, to, tokens);
        return true;
    }


    // ------------------------------------------------------------------------
    // Token owner can approve for `spender` to transferFrom(...) `tokens`
    // from the token owner's account
    //
    // https://github.com/ethereum/EIPs/blob/master/EIPS/eip-20-token-standard.md
    // recommends that there are no checks for the approval double-spend attack
    // as this should be implemented in user interfaces
    // ------------------------------------------------------------------------
    function approve(address spender, uint tokens) public returns (bool success) {
        allowed[msg.sender][spender] = tokens;
        emit Approval(msg.sender, spender, tokens);
        return true;
    }


    // ------------------------------------------------------------------------
    // Transfer `tokens` from the `from` account to the `to` account
    //
    // The calling account must already have sufficient tokens approve(...)-d
    // for spending from the `from` account and
    // - From account must have sufficient balance to transfer
    // - Spender must have sufficient allowance to transfer
    // - 0 value transfers are allowed
    // ------------------------------------------------------------------------
    function transferFrom(address from, address to, uint tokens) public returns (bool success) {
        balances[from] = balances[from].sub(tokens);
        allowed[from][msg.sender] = allowed[from][msg.sender].sub(tokens);
        balances[to] = balances[to].add(tokens);
        emit Transfer(from, to, tokens);
        return true;
    }


    // ------------------------------------------------------------------------
    // Returns the amount of tokens approved by the owner that can be
    // transferred to the spender's account
    // ------------------------------------------------------------------------
    function allowance(address tokenOwner, address spender) public view returns (uint remaining) {
        return allowed[tokenOwner][spender];
    }


    // ------------------------------------------------------------------------
    // Token owner can approve for `spender` to transferFrom(...) `tokens`
    // from the token owner's account. The `spender` contract function
    // `receiveApproval(...)` is then executed
    // ------------------------------------------------------------------------
    function approveAndCall(address spender, uint tokens, bytes data) public returns (bool success) {
        allowed[msg.sender][spender] = tokens;
        emit Approval(msg.sender, spender, tokens);
        ApproveAndCallFallBack(spender).receiveApproval(msg.sender, tokens, this, data);
        return true;
    }


    // ------------------------------------------------------------------------
    // Don't accept ETH
    // ------------------------------------------------------------------------
    function () public payable {
        revert();
    }


    // ------------------------------------------------------------------------
    // Owner can transfer out any accidentally sent ERC20 tokens
    // ------------------------------------------------------------------------
    function transferAnyERC20Token(address tokenAddress, uint tokens) public onlyOwner returns (bool success) {
        return ERC20Interface(tokenAddress).transfer(owner, tokens);
    }
}

Dito ako kumopya ng Code this wiki page
Ngayon Pindutin ang "Simula magtipon o Start to compile" at siguraduhin mong na walang compilation errors (Pulang mga mensahe)

Ngayon mag-log in sa iyong MetaMask browser extension at siguraduhin Remix ay konektado nito. Dapat ito ang lumabas katulad nito:

Baguhin ang token name na iyong gusto, simbolo at kabuuang supply:

 

Ngayon ay simple lang gawin ilipat ang contract sa FixedSupplyToken at pindutin ang Deploy button. Ayan!

Pagkatapos mong napindot yung Deploy button ang Remix ay magtatanong sayo ng kumpirmasyon

Kung ok lang sayo ang gas price na nagpapahiwatig sa iyo na magbayad at maari mo nang e-click "Confirm" baba ng sumolpot na window or Tab.
Dadalhin nito ang window ng Metamask na mukhang ganito:

Kung saan maaari nating makita ang ating pag-deploy ng kontrata ay nagkakahalaga sa ito ng $ 1.12
Ngayon pindutin ang  "Confirm" button at ang iyong kontrata ay dapat na deployed na ito sa Ethereum mainnet
0x0e0a6c613Ea16aE347CB98732e152530Ae9Bc7F2 gagamitin ko ito bilang isang example
Pagkatapos ng ilang minuto dapat itong makumpirma at makikita mo ang link sa iyong sariwang deploy na smart na kontrata sa listahan ng mga transaksyong Metamask. Narito ang transaksyon sa pag-deploy ng aking token:
https://etherscan.io/tx/0x6a39c40cc35eb03874808358eb0ab2ea9967c0c27f40fe3bf65c345fa2080da2
Token's smart contract address is: 0x0e0a6c613ea16ae347cb98732e152530ae9bc7f2
Ayos! Sa puntong ito ang aming token ay ganap na umaandar.

2. Kumpirmahin ang kontrata sa etherscan.io
Ito ay isang magandang ideya upang kumpirmahin ang iyong smart code ng kontrata sa etherscan.io kaya lahat ng tao ay magagawang tingnan ito nang madali. Dahil ang address ng kontrata ng aking token ay 0x0e0a6c613Ea16aE347CB98732e152530Ae9Bc7F2 Gagamitin ko ito bilang isang halimbawa

Pumunta sa pahina ng kontrata ng token sa etherscan.io:
https://etherscan.io/address/0x0e0a6c613ea16ae347cb98732e152530ae9bc7f2

Pindutin ang Code tab at pindutin ang Verify And Publish

Sa "I-verify ang Kontrata ng Code" dapat mong punan ang lahat ng kinakailangang mga patlang nang tama upang ma-verify ng etherscan ang code ng smart code ng iyong token:

I-click ang pindutan ng Verify at I-publish at kung ang lahat ng bagay ay mabuti dapat mong makita ang mga sumusunod:

Ngayon na ang code ng token ay na-verify kahit sino ay maaaring madaling suriin ito at siguraduhin na ito ay eksakto kung ano ang iyong inaangkin na ginagawa nito. Bukod dito ang token na ito ay karapat-dapat na nakalista sa https://einax.com

3. Paglista ng token on einax.com
Ang bahaging ito ay madali lamang i-drop sa amin ng isang mensahe sa pamamagitan ng Telegram na may isang link sa iyong na-verify na smart kontrata ng token.
Our telegram group ay: https://t.me/einax_exchange
Kapag ang iyong token ay nakalista sa einax.com maaari mong simulan ang pamamahagi nito sa pamamagitan ng airdrops sa isang malawak na madla o lumikha ng mga redeemable voucher kung kailangan mo ng mas personalized na diskarte. Ang lahat ng mga serbisyo ay libre. Plano rin naming ilunsad ang TOKEN / ETH trading pairs sa ika-1 ng Nobyembre, 2018. Ang iyong token ay awtomatikong ililista sa isang palitan.



PS: We've published a guide on how to launch your own AirDrops on einax platform. The good part is that you don't even have to deposit anything to test airdrops - every new account registered at einax.com receives 100 Welcome Tokens for free.
Original Post by Einax= https://bitcointalk.org/index.php?topic=5006219.0

[1713493140]

1713493140

[Hagmonar]

This is a a very technical post, (that is why there is no replies). In order to understand this one must posess a very basic knowledge in programming. Programmers and developers are the only ones who can understand this.

Maybe you can create another post in creating an ERC20 token in a manual way since this is the foundation in making cryptocurrency.

[Adriane14]

Creating a token and its success depends on the the idea cause without the idea it is just another basic play token. But anyone can build their own for small projects and big one. You can even create one for your football team if you want. I just hate when people abused it to make an exit ponzi and hyip projects. It does not add to the real revolutionary idea of Vitalik a DApp for the idealist not for jokers. Thanks for sharing!

[LogitechMouse]

This is a very techy post and maybe you can put this in Beginners and Help (must be in an English language of course). Few members will share there opinions regarding this. Anyway, there are a way where we can create ERC20 tokens by just inserting some values on some variables but unfortunately, I don't know this website .

[petyang12]

This is a very techy post and maybe you can put this in Beginners and Help (must be in an English language of course). Few members will share there opinions regarding this. Anyway, there are a way where we can create ERC20 tokens by just inserting some values on some variables but unfortunately, I don't know this website .

It is but this thread is translated from english and it's already in Beginners and Help. Did you read it all? I EVEN saw the provided link to the original thread. It is located below after the guide on how to create erc20 tokens or click here https://bitcointalk.org/index.php?topic=5006219.0

[ice18]

Good job Op well translated into our very own language infairness mas madali talagang intindihin kung naisalin sa sariling wika lalo na pag mga ganitong tutorials medyo techy at mahirap intindihin pag wala kang konteng background sa coding nakita ko rin to sa beginners kaso tinamad ako basahin haba e hehe for educational purposes lang dapat to bka yung iba jan gumawa ng fake ico at airdrops lol. 

[popkiko]

wow ayos ito for future porpuses at para sa may magagandang ideya na project nagusto gumawa ng sariling token pero sana wag gamitin sa pang scam ang ganto napakalaking tulong nito satin para kahit papano may ideya sa paggawa o pagpapatupadng ico gamit ang token.

[jemarie20]

wow ayos ito for future porpuses at para sa may magagandang ideya na project nagusto gumawa ng sariling token pero sana wag gamitin sa pang scam ang ganto napakalaking tulong nito satin para kahit papano may ideya sa paggawa o pagpapatupadng ico gamit ang token.

Tama ka magandang idea ito, dahil isa ding tanung saking isip iyan kong paano gumawa ng sariling token at kumita, dahil kong gagawa tayo ng sariling proyekto maslalaki ang ating kita, sana nga lang ay hindi ito gamitin ng mga taong walang magawa kundi ang manluko ng kapwa.

[aervin11]

I appreciate the post like other forum members does and this one is really helpful for me since I didn't know how that token creation/generation yet. I just noticed a misleading content that the OP was aware about and that was step number 3. I appreciate the idea but for listing your trial token on an exchange and airdrop it when you are aware that you didn't know what smart contract it is you are copying and sending to users, It's not a good idea at all. I appreciate the exchange and the post but for those who are trying to create a token using this one, please be aware of what you are doing and please avoid selling those trial tokens if you don't have to commitment to learn what smart contracts is and how your supposedly created token would work.

[john1010]

Mantakin mo, kadali lang pala gumawa ng ER20 token, kaya naman pala halos araw-araw ay may pinapanganak na ICO sa isang section dito sa BTT, Kaya doble ingat mga kabayan sa pag-invest sa mga ICO project, siguraduhing mabuti kung legit ang project, kasi nakita ko sa services section eh may nababayaran palang gumawa ng whitepaper, kumbaga eh meron ng ready template pala.

[Insanerman]

Mantakin mo, kadali lang pala gumawa ng ER20 token, kaya naman pala halos araw-araw ay may pinapanganak na ICO sa isang section dito sa BTT, Kaya doble ingat mga kabayan sa pag-invest sa mga ICO project, siguraduhing mabuti kung legit ang project, kasi nakita ko sa services section eh may nababayaran palang gumawa ng whitepaper, kumbaga eh meron ng ready template pala.

That is why there are lots of people who are getting scammed due to the lack of intensive research when choosing a project. Or maybe they just didn't think of their money whether it will go to waste to waste or to gain some profits.

Why do they create this kind of application if it is prone to such kind of illegal activities? It will just tempt  people to steal other people's money.

[miyaka26]

Mantakin mo, kadali lang pala gumawa ng ER20 token, kaya naman pala halos araw-araw ay may pinapanganak na ICO sa isang section dito sa BTT, Kaya doble ingat mga kabayan sa pag-invest sa mga ICO project, siguraduhing mabuti kung legit ang project, kasi nakita ko sa services section eh may nababayaran palang gumawa ng whitepaper, kumbaga eh meron ng ready template pala.

Mas madali sa ibang platform medyo kumplikado pa yan kesa sa ibang altcoins na supported yung token creation pero tama yan kunting kembot lang may ERC20 tokens kana at tinatake advantage naman ng mga panirang scammer para lang makapagnakaw ng pera sa iba kaya halos karamihan sa ICO kung hindi failed extended pa yung token sale gawa sa mga yan panira sa image.

[nakamura12]

Right guys, doble ingat lang kaya nga nag isip ako mag post nito ay dahil para mamulat sa katotohanan yung iba sa atin na madali nga gumawa ng token kaya di tayo basta basta mag invest or sumali ng ICOs. This is not bad to create pero we should know what we're going into having smart contract for. If marami nang Erc20 token ay di dahil sa easy lang gumawa, ang pera ay ang dahilan kung bakit nag take advantagr nito. This is post is to encouraged to create great purpose project and to also discouraged everyone on joining whatever ICO we could have seen that's why lots of people getting scam.

[petyang12]

Ingat lang tayo sa mga tao na greedy dahil ito amg dahilan kung bakit gagawing hindi maganda ang gumawa ng erc20 at tatawagin lang na shitcoins. Hindi naman lahat shitcoins, masyado lang talaga matakaw sa pera na pati erc20 gagamitan ng ponzi scheme.

[mOmenTOZ]

Mukang masyadong kumplikado pero kung susundin mo lang yung instructions which may take time, mukang madali lang naman. If ganito lang kadali gumawa ng ERC20 based tokens, hindi bat parang binabasura at winawalang hiya na lang ng iba ang cryptocurrency dahil they will be able to raise a selfdrop airdrops which can also be similar to scam? Kasi wala namang siryosong team behind those easy made tokens.

[petyang12]

Mukang masyadong kumplikado pero kung susundin mo lang yung instructions which may take time, mukang madali lang naman. If ganito lang kadali gumawa ng ERC20 based tokens, hindi bat parang binabasura at winawalang hiya na lang ng iba ang cryptocurrency dahil they will be able to raise a selfdrop airdrops which can also be similar to scam? Kasi wala namang siryosong team behind those easy made tokens.

Nasa tao ang gawa kaya kahit ano pa ang sabihin ng tao sa erc20 hindi maiiwasan na walang scam pero kung may seryoso talaga na team sigurado ako mas marami ang success na ICOs ngayon. Ang importante alam natin paano gumawa ng Erc20 tokens at kung mahirap ba gumawa o hindi para mas maisip natin na kailangan talaga mas maingat tayo sa erc20 tokens at kailangan mag research pa tungkol sa project nila para makaiwas tayo sa walang kwentang project na ponzi scheme lang sadya.

[wew13]

Salamat kababayan, naka gawa narin ako ng ERC20 salamat dahil sa information mo mas lalong lumalim ang aming natutunan about sa crypto!

[yugyug]

Kahit sa pag gawa ng ERC20 token ay hindi libre, dahil hindi ka maka buo ng token kung wala kang pundo ng ETHcoin na pambayad sa smart contract. Marami na ang nag-aabuso ng ERC20 token kaya ingat na lang tayo sa pag pili ng mga legit na project na may use cases or working product or MVP.