$ cat orig.txt 
1JR9vCVAtBsWDhYNZQ2kricThLMxWHKDfp
13mRysvzGQqTzLiLTgXRp2ghtqs9nWbdeS
1MjoeaszwcZEVLnNMiaZNsNj7UG3apfdFw
17msGTEYUk5nffmJuewnUEL87z4uHPZBs4
$ perl
#!/usr/bin/perl

use warnings;
use strict;
use LWP::UserAgent;

my $ua = LWP::UserAgent->new;
my %addrs_with_bal;

open my $infd, '<', "$ENV{'HOME'}/orig.txt" or die "open: $!";
while (<$infd>) {
    chomp;
    my $res = $ua->get ("https://blockchain.info/q/addressbalance/$_");
    if ($res->is_success) {
        my $bal = $res->content;
        $addrs_with_bal{$_} = undef if $bal;
    } else {
        warn sprintf "failed to get balance for address $_: %d %s\n", $res->code, $res->message;
    }
}
close $infd;

open my $outfd, '>', "$ENV{'HOME'}/dest.txt" or die "open: $!";
print $outfd "$_\n" for keys %addrs_with_bal;
close $outfd;
__END__
$ cat dest.txt 
1JR9vCVAtBsWDhYNZQ2kricThLMxWHKDfp
17msGTEYUk5nffmJuewnUEL87z4uHPZBs4
$ _

$ grep -r BN_init /usr/include/openssl/
/usr/include/openssl/bn.h:void	BN_init(BIGNUM *);

$ dpkg -l |grep ssl.*dev
ii  libssl-dev                        1.0.1e-2+deb7u15      amd64                 SSL development libraries, header files and documentation
ii  libssl-doc                        1.0.1e-2+deb7u15      all                   SSL development documentation documentation

#!/usr/bin/perl

use strict;
use warnings;
use Digest::SHA qw/sha256/;
use Crypt::Digest::RIPEMD160 qw/ripemd160/;
use Encode::Base58::GMP;
use Inline C => Config => LIBS => '-lssl';
use Inline C => <<'END_OF_C_CODE';
#include <stdio.h>
#include <stdlib.h>
#include <assert.h>
#include <openssl/ec.h>
#include <openssl/bn.h>

#define NID_secp256k1       714

SV* get_pubkey (char *pk) {
    EC_KEY *k = NULL;
    EC_POINT *pub_key = NULL;
    const EC_GROUP *group = NULL;
    BIGNUM start;
    BIGNUM *priv_key;
    BN_CTX *ctx;

    BN_init(&start);
    ctx = BN_CTX_new();
    assert(ctx);

    priv_key = &start;
    BN_hex2bn(&priv_key,pk);

    k = EC_KEY_new_by_curve_name(NID_secp256k1); assert(k);
    group = EC_KEY_get0_group(k); assert(group);
    pub_key = EC_POINT_new(group); assert(pub_key);
    assert(EC_POINT_mul(group, pub_key, priv_key, NULL, NULL, ctx)); assert(pub_key);

    char *hex = EC_POINT_point2hex(group, pub_key, POINT_CONVERSION_UNCOMPRESSED, ctx);
    SV *hex_copy = newSVpvf("%s", hex);
    OPENSSL_free(hex);

    return hex_copy;
}
END_OF_C_CODE

sub base58_gmp_to_btc {
    my ($base58) = @_; 
    $base58 =~ y|0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuv|123456789ABCDEFGHJKLMNPQRSTUVWXYZabcdefghijkmnopqrstuvwxyz|;
    return $base58;
}

sub b58_gmp {
    my ($str) = @_; 
    return base58_gmp_to_btc encode_base58 "0x$str", 'gmp';
}

sub checksum { return uc unpack 'H8', sha256 sha256 pack 'H*', shift }

sub hash160 { return unpack 'H*', ripemd160 sha256 pack 'H*', shift; }

my @leaders; @leaders[0,5] = (1, 3); 
sub b58ck {
    my ($ver, $str) = @_; 
    my $cksum = checksum "$ver$str";

    "$ver$str$cksum" =~ /^(0*)/;
    my $num_leading_0s = int +(length $1)/2;

    my $b58c = sprintf "%34s", b58_gmp  "$ver$str$cksum";

    my $b58 = $b58c;
    $b58 =~ s/ //g;
    $b58 = sprintf "%s$b58", $leaders[$ver]x$num_leading_0s;

    return $b58;
}

my $privkey = '1900966ca8703f337ad2c191718af367a04a1929685fe17e4b7fa3e1b9dd6d2d';  ## change me!
my $pubkey = get_pubkey $privkey;
my $h160 = hash160 $pubkey;
my $addr = b58ck '00', $h160;
print <<"EOF";
privkey $privkey
pubkey $pubkey
h160 $h160
addr $addr
EOF